it-swarm.com.ru

Пакетный цикл скриптов

Мне нужно выполнить команду 100-200 раз, и пока мое исследование показывает, что мне придется либо скопировать/вставить 100 копий этой команды, OR использовать цикл for, но цикл for ожидает список предметов, следовательно, мне нужно 200 файлов для работы или список из 200 предметов, чтобы победить точку.

Я бы предпочел не писать программу на С и пройти весь процесс документирования, почему мне пришлось написать другую программу для выполнения моей программы в тестовых целях. Модификация самой моей программы тоже не вариант.

Итак, учитывая команду a, как мне выполнить ее N раз с помощью пакетного сценария?

241
Tom J Nowell

for /l ваш друг:

for /l %x in (1, 1, 100) do echo %x

Начинается с 1, шаг за шагом и заканчивается на 100.

Используйте два %s, если он находится в командном файле

for /l %%x in (1, 1, 100) do echo %%x

(это одна из вещей, которые я действительно ненавижу в сценариях Windows)

Если у вас есть несколько команд для каждой итерации цикла, сделайте это:

for /l %x in (1, 1, 100) do (
   echo %x
   copy %x.txt z:\whatever\etc
)

или в пакетном файле

for /l %%x in (1, 1, 100) do (
   echo %%x
   copy %%x.txt z:\whatever\etc
)

Ключ:
/l означает, что команда for будет работать в числовом режиме, а не с набором файлов
%x - переменная циклов
(начальное значение, приращение значения, конечное условие [включительно])

472
Jon

И для перебора файлов каталога:

@echo off 
setlocal enableDelayedExpansion 

set MYDIR=C:\something
for /F %%x in ('dir /B/D %MYDIR%') do (
  set FILENAME=%MYDIR%\%%x\log\IL_ERROR.log
  echo ===========================  Search in !FILENAME! ===========================
  c:\utils\grep motiv !FILENAME!
)

Вы должны использовать "enableDelayedExpansion" и! FILENAME! вместо $ FILENAME $. Во втором случае DOS будет интерпретировать переменную только один раз (до того, как она войдет в цикл), а не каждый раз, когда программа зацикливается.

59
Olivier Faucheux

Шаблон для простого, но подсчитанного цикла:

set loopcount=[Number of times]
:loop
[Commands you want to repeat]
set /a loopcount=loopcount-1
if %loopcount%==0 goto exitloop
goto loop
:exitloop

Пример: скажите "Hello World!" 5 раз:

@echo off
set loopcount=5
:loop
echo Hello World!
set /a loopcount=loopcount-1
if %loopcount%==0 goto exitloop
goto loop
:exitloop
pause

Этот пример выведет:

Hello World!
Hello World!
Hello World!
Hello World!
Hello World!
Press any key to continue . . .
19
FluorescentGreen5

Вы также можете попробовать это вместо цикла for:

set count=0
:loop
set /a count=%count%+1
(Commands here)
if %count% neq 100 goto loop
(Commands after loop)

Это довольно мало, и это то, что я использую все время.

6
BlazeLP

Или вы можете уменьшить/увеличить переменную на количество циклов:

SETLOCAL ENABLEDELAYEDEXPANSION
SET counter=200
:Beginning
IF %counter% NEQ 0 (
echo %x
copy %x.txt z:\whatever\etc
SET /A counter=%counter%-1
GOTO Beginning
) ELSE (
ENDLOCAL
SET counter=
GOTO:eof

Очевидно, что использование FOR /L - это магистраль, и это обратный путь, который занимает больше времени, но он достигает того же пункта назначения.

6
Mechaflash

Вы можете сделать что-то для следующего эффекта, избегая цикла FOR.

set counter=0
:loop
echo "input commands here"
SET /A counter=%counter%+1
if %counter% GTR 200
(GOTO exit) else (GOTO loop)
:exit
exit
4
Marcus Culver

Вы можете сделать это без оператора for ^. ^:

@echo off
:SPINNER
SET COUNTP1=1

:1
CLS
 :: YOUR COMMAND GOES HERE
IF !COUNTP1! EQU 200 goto 2

SET COUNTP1=1
) ELSE (
SET /A COUNTP1+=1
)
goto 1

:2
:: COMMAND HAS FINISHED RUNNING 200 TIMES

У него есть базовое понимание. Просто проверь это. :П

2
zask

DOS не предлагает очень элегантных механизмов для этого, но я думаю, что вы все равно можете кодировать цикл для 100 или 200 итераций с разумными усилиями. Хотя нет числового цикла for, вы можете использовать символьную строку в качестве "переменной цикла".

Кодируйте цикл, используя GOTO, и для каждой итерации используйте SET X=%X%@, чтобы добавить еще один знак @ в переменную окружения X; и чтобы выйти из цикла, сравните значение X со строкой из 100 (или 200) @ знаков.

Я никогда не говорил, что это элегантно, но это должно сработать!

1
Carl Smotricz

Очень простой способ реализовать цикл в программировании cmd с использованием меток

@echo off
SET /A "index=1"
SET /A "count=5"
:while
if %index% leq %count% (
   echo The value of index is %index%
   SET /A "index=index + 1"
   goto :while
)
1
Rakesh Chaudhari

Ответ на самом деле зависит от того, насколько вы знакомы с пакетным режимом. Если у вас нет такого опыта, я бы порекомендовал увеличить переменную цикла:

@echo off
set /a loop=1
:repeat
echo Hello World!
set /a loop=%loop%+1
if %loop%==<no. of times to repeat> (
goto escapedfromrepeat
)
goto repeat
:escapedfromrepeat
echo You have come out of the loop
pause

Но если у вас больше опыта работы с пакетами, я бы порекомендовал более практичный вариант for /l %loop in (1, 1, 10) do echo %loop.

             (start at 1, go up in 1's, end at 10)
for /l %[your choice] (start, step, end) do [command of your choice]
0
Dr. Hugh Jarse

Я использую это. Это примерно то же самое, что и другие, но это просто еще один способ написать это.

@ECHO off
set count=0
:Loop
if %count%==[how many times to loop] goto end
::[Commands to execute here]
set count=%count%+1
goto Loop
:end
0
Jordan B

Не уверен, что такой ответ уже был отправлен, но вы можете попробовать что-то вроде этого:

@echo off
:start
set /a var+=1
if %var% EQU 100 goto end
:: Code you want to run goes here
goto start

:end
echo var has reached %var%.
pause
exit

Переменная% var% будет увеличиваться на единицу, пока не достигнет 100, после чего программа выведет, что она завершила выполнение. Опять же, не уверен, было ли это представлено или что-то подобное, но я думаю, что это может быть самым компактным.

0
Josh Girouard