it-swarm.com.ru

Как получить результат команды в переменной в Windows?

Я ищу, чтобы получить результат команды в качестве переменной в пакетном скрипте Windows (см. как получить результат команды в bash для эквивалентного сценария bash). Решение, которое будет работать в .bat-файле, предпочтительнее, но приветствуются и другие распространенные сценарии Windows. 

111
John Meagher

Если вам нужно захватить весь вывод команды, вы можете использовать такой пакет:

@ECHO OFF
IF NOT "%1"=="" GOTO ADDV
SET VAR=
FOR /F %%I IN ('DIR *.TXT /B /O:D') DO CALL %0 %%I
SET VAR
GOTO END

:ADDV
SET VAR=%VAR%!%1

:END

Все выходные строки хранятся в VAR с разделением "!".

@ Джон: есть ли практическое применение для этого? Я думаю, вы должны смотреть PowerShell или любой другой язык программирования, способный легко выполнять задачи сценариев (Python, Perl, PHP, Ruby)

29
PabloG

Скромная для команда накопила некоторые интересные возможности за эти годы:

D:\> FOR /F "delims=" %i IN ('date /t') DO set today=%i
D:\> echo %today%
Sat 20/09/2008

Обратите внимание, что "delims=" перезаписывает пробел по умолчанию и разделители табуляции, так что выходные данные команды date сожжены все сразу.

Для захвата многострочного вывода он по-прежнему может быть однострочным (используя переменную lf в качестве разделителя в результирующей переменной):

REM NB:in a batch file, need to use %%i not %i
setlocal EnableDelayedExpansion
SET lf=-
FOR /F "delims=" %%i IN ('dir \ /b') DO if ("!out!"=="") (set out=%%i) else (set out=!out!%lf%%%i)
ECHO %out%

Для захвата переданного по трубопроводу выражения используйте ^|:

FOR /F "delims=" %%i IN ('svn info . ^| findstr "Root:"') DO set "URL=%%i"
75
tardate

Чтобы получить текущий каталог, вы можете использовать это:

CD > tmpFile
SET /p myvar= < tmpFile
DEL tmpFile
echo test: %myvar%

Он использует временный файл, поэтому он не самый красивый, но он, безусловно, работает! «CD» помещает текущий каталог в «tmpFile», «SET» загружает содержимое tmpFile.

Вот решение для нескольких строк с "массивом":

@echo off

rem ---------
rem Obtain line numbers from the file
rem ---------

rem This is the file that is being read: You can replace this with %1 for dynamic behaviour or replace it with some command like the first example i gave with the 'CD' command.
set _readfile=test.txt

for /f "usebackq tokens=2 delims=:" %%a in (`find /c /v "" %_readfile%`) do set _max=%%a
set /a _max+=1
set _i=0
set _filename=temp.dat

rem ---------
rem Make the list
rem ---------

:makeList
find /n /v "" %_readfile% >%_filename%

rem ---------
rem Read the list
rem ---------

:readList
if %_i%==%_max% goto printList

rem ---------
rem Read the lines into the array
rem ---------
for /f "usebackq delims=] tokens=2" %%a in (`findstr /r "\[%_i%]" %_filename%`) do set _data%_i%=%%a
set /a _i+=1
goto readList

:printList
del %_filename%
set _i=1
:printMore
if %_i%==%_max% goto finished
set _data%_i%
set /a _i+=1
goto printMore

:finished

Но вы можете захотеть перейти на другую более мощную оболочку или создать приложение для этого. Это значительно расширяет возможности пакетных файлов.

23
Evil Activity

вам нужно использовать команду SET с параметром /P и направить свой вывод на него . Например, см. http://www.ss64.com/nt/set.html . Будет работать для CMD, не уверен насчет файлов .BAT

Из комментария к этому посту:

Эта ссылка имеет команду "Set /P _MyVar=<MyFilename.txt", которая говорит, что она установит _MyVar в первую строку из MyFilename.txt. Это могло быть используется как "myCmd > tmp.txt" с "set /P myVar=<tmp.txt". Но это будет только получить первую строку вывода, а не все выходные

7
Ilya Kochetov

Пример установки в переменную окружения "V" самого последнего файла 

FOR /F %I IN ('DIR *.* /O:D /B') DO SET V=%I

в пакетном файле вы должны использовать двойной префикс в переменной цикла:

FOR /F %%I IN ('DIR *.* /O:D /B') DO SET V=%%I
5
PabloG

Просто используйте результат команды FOR. Например (внутри командного файла):

for /F "delims=" %%I in ('dir /b /a-d /od FILESA*') do (echo %%I)

Вы можете использовать %%I в качестве значения, которое вы хотите. Просто так: %%I.

И заранее %%I не имеет пробелов или символов CR и может использоваться для сравнения !!

3
Raceableability
@echo off

ver | find "6.1." > nul
if %ERRORLEVEL% == 0 (
echo Win7
for /f "delims=" %%a in ('DIR "C:\Program Files\Microsoft Office\*Outlook.EXE" /B /P /S') do call set findoutlook=%%a
%findoutlook%
)

ver | find "5.1." > nul
if %ERRORLEVEL% == 0 (
echo WinXP
for /f "delims=" %%a in ('DIR "C:\Program Files\Microsoft Office\*Outlook.EXE" /B /P /S') do call set findoutlook=%%a
%findoutlook%
)
echo Outlook dir:  %findoutlook%
"%findoutlook%"
2
Hike

Если вы ищете решение, представленное в Использование результата команды в качестве аргумента в bash?

тогда вот код:

@echo off
if not "%1"=="" goto get_basename_pwd
for /f "delims=X" %%i in ('cd') do call %0 %%i
for /f "delims=X" %%i in ('dir /o:d /b') do echo %%i>>%filename%.txt
goto end

:get_basename_pwd
set filename=%~n1

:end
  • Это вызовет себя с результатом команды CD, такой же, как pwd.
  • Извлечение строки по параметрам вернет имя файла/папки.
  • Получить содержимое этой папки и добавить к имени файла .txt

[Credits]: Благодаря всем остальным ответам и некоторому копанию на Windows XP команды page.

2
Gustavo Carreno

Вы можете записать все выходные данные в одну переменную, но строки будут разделены символом по вашему выбору (# в приведенном ниже примере) вместо фактического CR-LF.

@echo off
setlocal EnableDelayedExpansion
for /f "delims=" %%i in ('dir /b') do (
    if "!DIR!"=="" (set DIR=%%i) else (set DIR=!DIR!#%%i)
)
echo directory contains:
echo %DIR%

Вторая версия, если вам нужно распечатать содержимое построчно. Это использует тот факт, что в dir/b не будет дублированных строк вывода, поэтому в общем случае это может не сработать.

@echo off
setlocal EnableDelayedExpansion
set count=0
for /f "delims=" %%i in ('dir /b') do (
    if "!DIR!"=="" (set DIR=%%i) else (set DIR=!DIR!#%%i)
    set /a count = !count! + 1
)

echo directory contains:
echo %DIR%

for /l %%c in (1,1,%count%) do (
    for /f "delims=#" %%i in ("!DIR!") do (
        echo %%i
        set DIR=!DIR:%%i=!
    )
)
1
Adam Mitz

Я хотел бы добавить замечание к вышеупомянутым решениям:

Все эти синтаксисы работают отлично, ЕСЛИ ВАША КОМАНДА IS НАЙДЕТСЯ В ПУТИ, или ЕСЛИ КОМАНДА IS, cmdpath БЕЗ ПРОСТРАНСТВ OR СПЕЦИАЛЬНЫХ ПЕРСОНАЖЕЙ.

Но если вы попытаетесь использовать исполняемую команду, расположенную в папке, путь к которой содержит специальные символы, вам потребуется заключить путь к команде в двойные кавычки ("), и тогда синтаксис FOR/F не будет работать.

Примеры:

$ for /f "tokens=* USEBACKQ" %f in (
    `""F:\GLW7\Distrib\System\Shells and scripting\f2ko.de\folderbrowse.exe"" Hello '"F:\GLW7\Distrib\System\Shells and scripting"'`
) do echo %f
The filename, directory name, or volume label syntax is incorrect.

или же 

$ for /f "tokens=* USEBACKQ" %f in (
      `"F:\GLW7\Distrib\System\Shells and scripting\f2ko.de\folderbrowse.exe" "Hello World" "F:\GLW7\Distrib\System\Shells and scripting"`
) do echo %f
'F:\GLW7\Distrib\System\Shells' is not recognized as an internal or external command, operable program or batch file.

или же 

`$ for /f "tokens=* USEBACKQ" %f in (
     `""F:\GLW7\Distrib\System\Shells and scripting\f2ko.de\folderbrowse.exe"" "Hello World" "F:\GLW7\Distrib\System\Shells and scripting"`
) do echo %f
'"F:\GLW7\Distrib\System\Shells and scripting\f2ko.de\folderbrowse.exe"" "Hello' is not recognized as an internal or external command, operable program or batch file.

В этом случае единственное решение, которое я нашел для использования команды и сохранения ее результата в переменной, - это установить (временно) каталог по умолчанию в каталог самой команды:

pushd "%~d0%~p0"
FOR /F "tokens=* USEBACKQ" %%F IN (
    `FOLDERBROWSE "Hello world!" "F:\GLW7\Distrib\System\Layouts (print,display...)"`
) DO (SET MyFolder=%%F)
popd
echo My selected folder: %MyFolder%

Результат тогда правильный:

My selected folder: F:\GLW7\Distrib\System\OS install, recovery, VM\
Press any key to continue . . .

Конечно, в приведенном выше примере я предполагаю, что мой пакетный скрипт находится в той же папке, что и моя исполняемая команда, так что я могу использовать синтаксис «% ~ d0% ~ p0». Если это не ваш случай, вам нужно найти способ найти путь к вашей команде и изменить каталог по умолчанию на его путь.

NB. Для тех, кто интересуется, здесь приведен пример команды (для выбора папки) FOLDERBROWSE.EXE. Я нашел это на веб-сайте f2ko.de ( http://f2ko.de/en/cmd.php ).

Если у кого-то есть лучшее решение для такого рода команд, доступное по сложному пути, я буду очень рад услышать об этом.

Жилль

1
Gilles Maisonneuve

Вы должны использовать команду for, вот пример:

@echo off
rem Commands go here
exit /b
:output
for /f "tokens=* useback" %%a in (`%~1`) do set "output=%%a"

и вы можете использовать call :output "Command goes here", тогда вывод будет в переменной %output%.

Примечание: Если у вас есть вывод команды, который является многострочным, этот инструмент будет set вывод в последнюю строку вашей многострочной команды.

0
Hayz
@echo off
setlocal EnableDelayedExpansion
FOR /F "tokens=1 delims= " %%i IN ('echo hola') DO (
    set TXT=%%i
)
echo 'TXT: %TXT%'

результат «TXT: привет»

0
ivan rc