it-swarm.com.ru

Как мне выводить и отправлять вывод консоли на файл в скрипте bat?

У меня есть пакетный скрипт, который выполняет задачу и отправляет вывод в текстовый файл. Есть ли способ отобразить вывод в окне консоли?

Например:

c:\Windows>dir > windows-dir.txt

Есть ли способ, чтобы вывод dir отображался в окне консоли, а также помещался в текстовый файл?

130
JamesEggers

Нет, вы не можете с чистым перенаправлением.
Но с некоторыми хитростями (например, tee.bat ) вы можете.

Я пытаюсь объяснить перенаправление немного.

Вы перенаправляете один из десяти потоков с помощью > файла или <файла
Неважно, если перенаправление происходит до или после команды, поэтому эти две строки почти одинаковы.

dir > file.txt
> file.txt dir

Перенаправление в этом примере является только ярлыком для 1> , это означает, что поток 1 (STDOUT) будет перенаправлен.
Таким образом, вы можете перенаправить любой поток с добавлением числа наподобие 2> err.txt , а также разрешено перенаправлять несколько потоков в одном линия.

dir 1> files.txt 2> err.txt 3> nothing.txt

В этом примере "стандартный вывод" будет помещен в файл files.txt, все ошибки будут в файле err.txt, а stream3 - в none.txt (DIR не использует поток 3).
Stream0 - это STDIN
Stream1 - STDOUT
Stream2 - это STDERR
Stream3-9 не используются

Но что произойдет, если вы попытаетесь перенаправить один и тот же поток несколько раз?

dir > files.txt > two.txt

"Может быть только один", и он всегда последний!
Таким образом, он равен dir> two.txt

Хорошо, есть одна дополнительная возможность, перенаправление потока в другой поток.

dir 1>files.txt 2>&1 

2> & 1 перенаправляет stream2 в stream1 и 1> files.txt перенаправляет все в files.txt .
Порядок важен здесь!

dir ... 1>nul 2>&1
dir ... 2>&1 1>nul

разные. Первый перенаправляет все (STDOUT и STDERR) в NUL,
, но вторая строка перенаправляет STDOUT в NUL и STDERR в "пустой" STDOUT.

В качестве одного из выводов очевидно, что примеры Otávio Décio и andynormancx не работают.

command > file >&1
dir > file.txt >&2

Оба пытаются перенаправить stream1 два раза, но "может быть только один", и он всегда последний.
Итак, вы получите

command 1>&1
dir 1>&2

И в первом примере перенаправление stream1 на stream1 не разрешено (и не очень полезно).

Надеюсь, поможет.

211
jeb

Просто используйте версию для Windows UNIX tee (находится по адресу http://unxutils.sourceforge.net ) следующим образом:

mycommand > tee outpu_file.txt

Если вам также нужен выход STDERR, используйте следующее.
2>&1 объединяет вывод STDERR в STDOUT (основной поток).

mycommand 2>&1 | tee output_file.txt
32
atn

Если вам не нужен вывод в режиме реального времени (то есть, когда программа его пишет), вы можете добавить

type windows-dir.txt

после этой строки.

9
Mark Pim

Решение, которое работало для меня, было: dir> a.txt | type a.txt .

7
NSPKUWCExi2pr8wVoGNk

Да, есть способ показать вывод одной команды на консоли (экране) и в файле. Используя ваш пример, используйте ...

@ECHO OFF
FOR /F "tokens=*" %%I IN ('DIR') DO ECHO %%I & ECHO %%I>>windows-dir.txt

Детальное объяснение:

Команда FOR анализирует выходные данные команды или текста в переменную, на которую можно ссылаться несколько раз.

Для команды, такой как DIR /B, заключите в одинарные кавычки, как показано в примере ниже. Замените текст DIR /B желаемой командой.

FOR /F "tokens=*" %%I IN ('DIR /B') DO ECHO %%I & ECHO %%I>>FILE.TXT

Для отображения текста заключите текст в двойные кавычки, как показано в примере ниже.

FOR /F "tokens=*" %%I IN ("Find this text on console (screen) and in file") DO ECHO %%I & ECHO %%I>>FILE.TXT

... и с переносом строк ...

FOR /F "tokens=*" %%I IN ("Find this text on console (screen) and in file") DO (
  ECHO %%I & ECHO %%I>>FILE.TXT
)

Если у вас есть моменты, когда вы хотите, чтобы вывод выводился только на консоли (экран), и другие разы, отправленные только в файл, и другие разы, отправляемые в оба, укажите условие "DO" цикла FOR с помощью переменной, как показано ниже с %TOECHOWHERE% ,.

@ECHO OFF
FOR %%I IN (TRUE FALSE) DO (
  FOR %%J IN (TRUE FALSE) DO (
    SET TOSCREEN=%%I & SET TOFILE=%%J & CALL :Runit)
)
GOTO :Finish

:Runit
  REM Both TOSCREEN and TOFILE get assigned a trailing space in the FOR loops
  REM above when the FOR loops are evaluating the first item in the list,
  REM "TRUE".  So, the first value of TOSCREEN is "TRUE " (with a trailing
  REM space), the second value is "FALSE" (no trailing or leading space).
  REM Adding the ": =" text after "TOSCREEN" tells the command processor to
  REM remove all spaces from the value in the "TOSCREEN" variable.
  IF "%TOSCREEN: =%"=="TRUE" (
      IF "%TOFILE: =%"=="TRUE" (
          SET TEXT=On screen, and in "FILE.TXT"
          SET TOECHOWHERE="ECHO %%I & ECHO %%I>>FILE.TXT"
        ) ELSE (
          SET TEXT=On screen, not in "FILE.TXT"
          SET TOECHOWHERE="ECHO %%I"
      )
    ) ELSE (
      IF "%TOFILE: =%"=="TRUE" (
          SET TEXT=Not on screen, but in "FILE.TXT"
          SET TOECHOWHERE="ECHO %%I>>FILE.txt"
        ) ELSE (
          SET TEXT=Not on screen, nor in "FILE.TXT"
          SET TOECHOWHERE="ECHO %%I>NUL"
      )
  )
  FOR /F "tokens=*" %%I IN ("%TEXT%") DO %TOECHOWHERE:~1,-1%
GOTO :eof

:Finish
  ECHO Finished [this text to console (screen) only].
  PAUSE
6
Amazinate
command > file >&1
3
Otávio Décio

Если вы хотите добавить вместо замены выходной файл, вы можете использовать

dir 1>> files.txt 2>> err.txt

или же

dir 1>> files.txt 2>>&1
2
Jochen

Мне нравится ответ atn, но скачать его было не так тривиально, как wintee , который также является открытым исходным кодом и дает только функциональность tee (полезно, если вы просто хотите использовать tee, а не весь набор unix коммунальные услуги). Я узнал об этом из ответа Давора на отображение вывода командной строки Windows и перенаправление его в файл , где вы также найдете ссылку на утилиты unix.

1
sage

Я сделал простую консоль C #, которая может обрабатывать вывод в режиме реального времени на экран cmd и журнал

class Tee
{
    static int Main(string[] args)
    {
        try
        {
            string logFilePath = Path.GetFullPath(args[0]);

            using (StreamWriter writer = new StreamWriter(logFilePath, true))
            {
                for (int value; (value = Console.In.Read()) != -1;)
                {
                    var Word = Char.ConvertFromUtf32(value);
                    Console.Write(Word);
                    writer.Write(Word);
                }
            }
        }
        catch (Exception)
        {
            return 1;
        }
        return 0;
    }
}

Использование командного файла такое же, как и использование Unix tee

foo | tee xxx.log

А вот репозиторий, в который входит Tee.exe, если у вас нет инструмента для компиляции https://github.com/iamshiao/Tee

1
蕭為元

Мой вариант был такой:

Создайте подпрограмму, которая принимает сообщение и автоматизирует процесс отправки его как в консоль, так и в файл журнала.

setlocal
set logfile=logfile.log

call :screenandlog "%DATE% %TIME% This message goes to the screen and to the log"    

goto :eof

:screenandlog
set message=%~1
echo %message% & echo %message% >> %logfile%
exit /b

Если вы добавляете переменную к сообщению, обязательно удалите кавычки в нем, прежде чем отправлять его в подпрограмму, иначе он может испортить вашу партию. Конечно, это работает только для эха.

1
JPZ

Решение, предоставленное "Tomas R", идеально подходит для вопроса ОП и доступно изначально.

Попробуйте: chkdsk c:> output.txt | введите output.txt

Вывод этой команды включает процент выполнения, который последовательно выводится в файл, следовательно, он будет выглядеть немного грязно (то есть текст будет добавляться по мере его выполнения). Этого не происходит с битами, которые выводятся на STDOUT (экран). Это так, как если бы вы просто делали одну и ту же команду без перенаправления.

0
J0N