it-swarm.com.ru

Запустить хранимую процедуру в SQL Developer?

Я пытаюсь запустить хранимую процедуру, которая имеет несколько входных и выходных параметров. Процедуру можно просмотреть только на панели «Подключения», перейдя по ссылке «Другие пользователи» | | Пакеты | | 

Если я щелкну правой кнопкой мыши, пункты меню будут "Упорядочить элементы по ..." и "Создать модульный тест" (выделены серым цветом). Возможность «Запустить» процедуру не представляется возможной, когда к ней обращается пользователь.

Я пытался найти пример того, как создать анонимный блок, чтобы я мог запустить процедуру в виде файла SQL, но не нашел ничего, что работает.

Кто-нибудь знает, как я могу выполнить эту процедуру из SQL Developer? Я использую версию 2.1.1.64.

Заранее спасибо!

Правка 1:

Процедура, которую я хочу вызвать, имеет следующую подпись:

user.package.procedure(
   p_1 IN  NUMBER,
   p_2 IN  NUMBER,
   p_3 OUT VARCHAR2,
   p_4 OUT VARCHAR2,
   p_5 OUT VARCHAR2,
   p_6 OUT NUMBER)

Если я напишу свой анонимный блок так:

DECLARE
   out1 VARCHAR2(100);
   out2 VARCHAR2(100);
   out3 VARCHAR2(100);
   out4 NUMBER(100);
BEGIN
   EXECUTE user.package.procedure (33,89, :out1, :out2, :out3, :out4);
END;

Я получаю ошибку:

Bind Varialbe "out1" is NOT DECLCARED
anonymous block completed

Я попытался инициализировать переменные out *:

   out1 VARCHAR2(100) := '';

но получите ту же ошибку:

Правка 2:

Основываясь на ответе Алекса, я попытался удалить двоеточия перед параметрами и получить это:

Error starting at line 1 in command:
DECLARE
   out1 VARCHAR2(100);
   out2 VARCHAR2(100);
   out3 VARCHAR2(100);
   out4 NUMBER(100);
BEGIN
   EXECUTE user.package.procedure (33,89, out1, out2, out3, out4);
END;
Error report:
ORA-06550: line 13, column 17:
PLS-00103: Encountered the symbol "USER" when expecting one of the following:

   := . ( @ % ; immediate
The symbol ":=" was substituted for "USER" to continue.
06550. 00000 -  "line %s, column %s:\n%s"
*Cause:    Usually a PL/SQL compilation error.
*Action:
69
sdoca

С простыми типами параметров (то есть без рефкурсоров и т.д.) Вы можете сделать что-то вроде этого:

SET serveroutput on;
DECLARE
    InParam1 number;
    InParam2 number;
    OutParam1 varchar2(100);
    OutParam2 varchar2(100);
    OutParam3 varchar2(100);
    OutParam4 number;
BEGIN
    /* Assign values to IN parameters */
    InParam1 := 33;
    InParam2 := 89;

    /* Call procedure within package, identifying schema if necessary */
    schema.package.procedure(InParam1, InParam2,
        OutParam1, OutParam2, OutParam3, OutParam4);

    /* Display OUT parameters */
    dbms_output.put_line('OutParam1: ' || OutParam1);
    dbms_output.put_line('OutParam2: ' || OutParam2);
    dbms_output.put_line('OutParam3: ' || OutParam3);
    dbms_output.put_line('OutParam4: ' || OutParam4);
END;
/


Отредактировано для использования спецификации OP и с альтернативным подходом для использования переменных связывания :var:

var InParam1 number;
var InParam2 number;
var OutParam1 varchar2(100);
var OutParam2 varchar2(100);
var OutParam3 varchar2(100);
var OutParam4 number;

BEGIN
    /* Assign values to IN parameters */
    :InParam1 := 33;
    :InParam2 := 89;

    /* Call procedure within package, identifying schema if necessary */
    schema.package.procedure(:InParam1, :InParam2,
        :OutParam1, :OutParam2, :OutParam3, :OutParam4);
END;
/

-- Display OUT parameters
print :OutParam1;
print :OutParam2;
print :OutParam3;
print :OutParam4;
71
Alex Poole

Выполнять легко. Получить результаты может быть сложно. 

Посмотрите на этот вопрос, который я задал Лучший способ/инструмент для получения результатов от процедуры пакета Oracle

Краткое изложение этого выглядит следующим образом.

Предполагая, что у вас есть пакет с именем mypackage и процедура с именем getQuestions. Возвращает refcursor и принимает строковое имя пользователя.

Все, что вам нужно сделать, это создать новый файл SQL (файл новый). Установите соединение и вставьте следующее и выполните.

var r refcursor;
exec mypackage.getquestions(:r, 'OMG Ponies');
print r;
25
Conrad Frix

Для тех, кто использует SqlDeveloper 3+, если вы пропустили это:

SqlDeveloper имеет функцию непосредственного выполнения хранимых процедур/функций, а выходные данные отображаются в удобном для чтения виде.

Просто щелкните правой кнопкой мыши на пакете/сохраненной процедуре/сохраненной функции, щелкните Run и выберите target в качестве процедуры/функции, которую вы хотите выполнить, SqlDeveloper сгенерирует фрагмент кода для выполнения (чтобы вы могли поместить свои входные параметры). После выполнения выходные параметры отображаются в нижней половине диалогового окна и даже имеют встроенную поддержку ref cursor: результат курсора будет отображаться в виде отдельной вкладки вывода.

16
Adrian Shum

Откройте процедуру в SQL Developer и запустите ее оттуда. SQL Developer отображает SQL, который он запускает.

BEGIN
  PROCEEDURE_NAME_HERE();
END;
11
Noel

Использование:

BEGIN

  PACKAGE_NAME.PROCEDURE_NAME(parameter_value, ...);

END;

Замените «PACKAGE_NAME», «PROCEDURE_NAME» и «parameter_value» тем, что вам нужно. Параметры OUT должны быть объявлены до.

6
OMG Ponies

Ни один из этих ответов не помог мне. Вот что мне нужно было сделать, чтобы запустить процедуру в SQL Developer 3.2.20.10:

SET serveroutput on;
DECLARE
  testvar varchar(100);
BEGIN
  testvar := 'dude';
  schema.MY_PROC(testvar);
  dbms_output.enable;
  dbms_output.put_line(testvar);
END;

И тогда вам нужно будет проверить таблицу на предмет того, что ваш proc должен был делать с этой переданной переменной - выходные данные просто подтвердят, что переменная получила значение (и теоретически передала его в proc).

ПРИМЕЧАНИЕ(различия с моим против других): 

  • Нет : перед именем переменной
  • Не ставьте .package. или .packages. между именем схемы и именем процедуры
  • Нет необходимости помещать & в значение переменной.
  • Не используйте print в любом месте
  • Не используйте var для объявления переменной

Все эти проблемы заставили меня долго ломать голову, и эти ответы, в которых есть эти вопиющие ошибки, должны быть устранены, обработаны и обработаны.

1
vapcguy

С помощью SQL Developer версии 4.0.2.15 Build 15.21 работает следующее:

SET SERVEROUTPUT ON
var InParam1 varchar2(100)
var InParam2 varchar2(100)
var InParam3 varchar2(100)
var OutParam1 varchar2(100)

BEGIN
    /* Assign values to IN parameters */
    :InParam1 := 'one';
    :InParam2 := 'two';
    :InParam3 := 'three';

    /* Call procedure within package, identifying schema if necessary */
    schema.package.procedure(:InParam1, :InParam2, :InParam3, :OutParam1);
    dbms_output.enable;
    dbms_output.put_line('OutParam1: ' || :OutParam1);
END;
/
0
Jack

Хотя этот вопрос довольно старый, я продолжаю натыкаться на тот же результат, не находя простой способ запуска из sql developer ..__ После нескольких попыток я нашел простой способ выполнить хранимую процедуру от самого разработчика sql. 

  • Под пакетами выберите нужный пакет и щелкните правой кнопкой мыши на имени пакета (не на имени хранимой процедуры).

  • Вы найдете вариант для запуска. Выберите это и предоставьте необходимые аргументы. Нажмите OK, и вы можете увидеть результат в разделе выходных переменных ниже

Я использую SQL Developer версии 4.1.3.20

0
Narasimha

Не могу поверить, это не будет выполняться в SQL Developer: 

var r refcursor;
exec PCK.SOME_SP(:r,
 '02619857');

print r;

НО это будет:

var r refcursor;
exec TAPI_OVLASCENJA.ARH_SELECT_NAKON_PRESTANKA_REG(:r, '02619857');

print r;

Очевидно, все должно быть в одной строке ..

0
Amel Music