it-swarm.com.ru

Как создать поливариадную функцию haskell?

Мне нужна функция, которая принимает произвольное количество аргументов (все одного и того же типа), что-то делает с ними и впоследствии возвращает результат. Список аргументов неосуществим в моем конкретном случае.

Просматривая библиотеки haskell, я увидел, что функция printf (из модуля Text.Printf) использует аналогичный прием. К сожалению, я не мог понять эту магию, посмотрев на источник.

Может кто-нибудь объяснить, как этого добиться, или, по крайней мере, какую-нибудь веб-страницу/бумагу/что-нибудь еще, где я мог бы найти хорошее описание для этого?

мотивация:

Причина, по которой мне это нужно, очень проста. Для школы (урок информатики) мы должны написать модуль, который может "записывать" математическое выражение, выражать его в виде строки (посредством записи экземпляра Num/Real/и т.д. Для собственного типа данных) и выполнять различные операции над ним.

Этот тип данных содержит специальный конструктор для переменной, который может быть заменен значением или чем-то еще указанной функцией. Одна из целей - написать функцию, которая принимает такое выражение с некоторым количеством переменных (пары типа (Char,Rational)) и вычисляет результат выражения. Мы должны посмотреть, как лучше выразить цель функции. (Моя идея: функция возвращает другую функцию, которая принимает столько же аргументов, сколько и переменных, определенных в функции - кажется невозможным).

67
fuz

Ключевым моментом printf является возможность либо вернуть строку, либо функцию. Скопировано из http://www.haskell.org/ghc/docs/6.12.2/html/libraries/base-4.2.0.1/src/Text-Printf.html ,

printf :: (PrintfType r) => String -> r
printf fmts = spr fmts []

class PrintfType t where
    spr :: String -> [UPrintf] -> t

instance (IsChar c) => PrintfType [c] where
    spr fmts args = map fromChar (uprintf fmts (reverse args))

instance (PrintfArg a, PrintfType r) => PrintfType (a -> r) where
    spr fmts args = \a -> spr fmts (toUPrintf a : args)

и основная структура, которую мы можем извлечь, это

variadicFunction :: VariadicReturnClass r => RequiredArgs -> r
variadicFunction reqArgs = variadicImpl reqArgs mempty

class VariadicReturnClass r where
   variadicImpl :: RequiredArgs -> AccumulatingType -> r

instance VariadicReturnClass ActualReturnType where
   variadicImpl reqArgs acc = constructActualResult reqArgs acc

instance (ArgClass a, VariadicReturnClass r) => VariadicReturnClass (a -> r) where
   variadicImpl reqArgs acc = \a -> variadicImpl reqArgs (specialize a `mappend` acc)

Например:

class SumRes r where 
    sumOf :: Integer -> r

instance SumRes Integer where
    sumOf = id

instance (Integral a, SumRes r) => SumRes (a -> r) where
    sumOf x = sumOf . (x +) . toInteger

тогда мы могли бы использовать

*Main> sumOf 1 :: Integer
1
*Main> sumOf 1 4 7 10 :: Integer
22
*Main> sumOf 1 4 7 10 0 0  :: Integer
22
*Main> sumOf 1 4 7 10 2 5 8 22 :: Integer
59
99
kennytm

Многие люди говорят вам, как создавать переменные функции, но я думаю, что в этом случае вам действительно лучше просто использовать список типа [(Char, Rational)].

9
user370536

Ответ Кенни ТМ великолепен. Ниже приведен пример процесса exec sumOf 1 4 7 10 :: Integer для лучшей иллюстрации.

sumOf 1 4 7 10
(( \ x -> ( sumOf . (x +) . toInteger ) 1 ) 4 7 10
((sumOf . (1 + ) . toInteger) 4 ) 7 10
( sumOf 5 ) 7 10
( sumOf . (5 + ) . toInteger ) 7 10
sumOf 12 10
sumOf . (12 + ) . toInteger 10
sumof 22
id 22
22
7
lispc

В вики-статье о функциях с переменными ссылками указывалось эта статья . Я полагаю, это то, что делает printf, но я тоже этого не понимаю. В любом случае, это определенно излишнее, особенно если учесть, что все ваши аргументы одного типа. Просто поместите их все в один список. Вот для чего хороши списки - произвольное количество вещей одного типа. Хорошо, это не очень красиво, но вряд ли будет уродливее полной поливариадной функции.

7
user395760

Я посмотрел на пример ссылку из статьи, на которую ссылался Делнан. Посмотрев на это немного, я, наконец, понял, что происходит:

Это начинается с этого типа класса:

class BuildList a r  | r-> a where
    build' :: [a] -> a -> r

Этот бит после канала (|) является функциональной зависимостью. Он говорит, что тип, представленный a, может быть определен типом, представленным r. Другими словами, вам запрещено определять два экземпляра класса типов BuildList с одинаковым r (тип возвращаемого значения), но с другим a.

Немного забегая вперед, туда, где фактически используется функция build':

> build True :: [Bool]

Поскольку build просто вызывает build' с пустым списком в качестве первого параметра, это то же самое, что и:

> build' [] True :: [Bool]

В этом примере build' явно возвращает список. Из-за функциональной зависимости мы можем связываться только с этим экземпляром класса типа BuildList:

instance BuildList a [a] where
    build' l x = reverse$ x:l

Довольно просто. Второй пример более интересный. Расширяя определение build, оно становится:

> build' [] True False :: [Bool]

Какой тип build' в этом случае? Ну, правила предшествования Haskell означают, что вышеприведенное также может быть написано так:

> (build' [] True) False :: [Bool]

Теперь становится ясно, что мы передаем два параметра в build' и затем применяем результат этого выражения к параметру со значением "False". Другими словами, ожидается, что выражение (build' [] True) возвратит функцию типа Bool -> [Bool]. И это связывает нас со вторым экземпляром класса типов BuildList:

instance BuildList a r => BuildList a (a->r) where
    build' l x y = build'(x:l) y

В этом вызове l = [] и x = True и y = False, поэтому определение расширяется до build' [True] False :: [Bool]. Эта подпись привязывается к первому экземпляру build', и совершенно очевидно, откуда она идет.

6
Daniel Pratt