it-swarm.com.ru

Проверьте, существует ли какой-либо тип файлов в каталоге, используя скрипт BATCH

Здравствуйте, я ищу написать командный файл, чтобы проверить, есть ли какие-либо файлы любого типа в данной папке.

Пока я пробовал следующее

if EXIST FOLDERNAME\\*.* ( echo Files Exist ) ELSE ( echo "Empty" ) 

Я могу заставить это работать, если я знаю расширение файла, такое как файл txt с следующим

if EXIST FOLDERNAME\\*.txt ( echo Files Exist ) ELSE ( echo "Empty" )

Спасибо за помощь

30
psycho

Чтобы проверить, содержит ли папка хотя бы один файл

>nul 2>nul dir /a-d "folderName\*" && (echo Files exist) || (echo No file found)

Чтобы проверить, содержит ли папка или какой-либо из ее потомков хотя бы один файл

>nul 2>nul dir /a-d /s "folderName\*" && (echo Files exist) || (echo No file found)

Чтобы проверить, содержит ли папка хотя бы один файл или папку.
Обратите внимание на добавление /a возможность включить поиск скрытых и системных файлов/папок.

dir /b /a "folderName\*" | >nul findstr "^" && (echo Files and/or Folders exist) || (echo No File or Folder found)

Чтобы проверить, содержит ли папка хотя бы одну папку

dir /b /ad "folderName\*" | >nul findstr "^" && (echo Folders exist) || (echo No folder found)
41
dbenham

Для файлов в каталоге вы можете использовать такие вещи, как:

if exist *.csv echo "csv file found"

или

if not exist *.csv goto nofile
9
Maikel

Вы можете использовать это

@echo off
for /F %%i in ('dir /b "c:\test directory\*.*"') do (
   echo Folder is NON empty
   goto :EOF
)
echo Folder is empty or does not exist

Взято из здесь .

Это должно делать то, что вам нужно.

6
Bali C